Tutorial 04 | Terraform – toicodemoingay

01

of 10

Introduction

In the previous post, we learned about the life cycle of a resource in Terraform. In this lecture, we will learn how to program in Terraform.

Terraform supports us in the Functional Programming style.

02

of 10

Create EC2

We will do an EC2 example to learn about programming concepts in Terraform. Create a file named main.tf

provider "aws" {
  region = "us-west-2"
}

data "aws_ami" "ubuntu" {
  most_recent = true

  filter {
    name   = "name"
    values = ["ubuntu/images/hvm-ssd/ubuntu-focal-20.04-amd64-server-*"]
  }

  owners = ["099720109477"]
}

resource "aws_instance" "hello" {
  ami           = data.aws_ami.ubuntu.id
  instance_type = "t2.micro"
}

Run terraform init and terraform apply, then on AWS we will see our EC2. With the above code, our EC2 always has an instance_type of t2.micro. What if we want to recreate EC2 but have a different instance_type? Shall we modify the code in the Terraform file? In this case, we will use variables (called variables in programming) to accomplish this.

03

of 10

Input variable declaration

We can define variables for Terraform with the following syntax:

This is the variable block syntax for declaring variables. In the above example, we create one more file with the name variable.tf (you can name it whatever you want) to declare our variable.

variable "instance_type" {
  type = string
  description = "Instance type of the EC2"
}

The type attribute is used to specify the variable’s data type, and the description attribute is used to record a description that tells the reader what the variable means. For your information, the type attribute is mandatory, and the description attribute is optional. In Terraform, a variable will have the following data types:

Basic Type: string, number, bool
Complex Type: list(), set(), map(), object(), tuple()

In Terraform, the number and bool data types will be converted to string data types when necessary. That is, 1 will become “1”, and true will become “true”.

We use the syntax var.<VARIABLE_NAME> to access the variable’s value and update the main.tf file.

provider "aws" {
  region = "us-west-2"
}

data "aws_ami" "ubuntu" {
  most_recent = true

  filter {
    name   = "name"
    values = ["ubuntu/images/hvm-ssd/ubuntu-focal-20.04-amd64-server-*"]
  }

  owners = ["099720109477"]
}

resource "aws_instance" "hello" {
  ami           = data.aws_ami.ubuntu.id
  instance_type = var.instance_type # change here
}

In the instance_type attribute, instead of hard assignment, we will now use the variable var.instance_type.

04

of 10

Assign a value to a variable

To assign a value to a variable, we will create a file called terraform.tfvars.

instance_type = "t2.micro"

When we run the terraform apply command, the terraform.tfvars file will be used by Terraform to load the default value for the variable. If we don’t want to use the default, then when we run the apply command, we add the -var-file attribute.

Now, let’s create a file called production.tfvars.

instance_type = "t3.small"

When running CI/CD for production, we specify the file as follows:

terraform apply -var-file="production.tfvars"

Now our instance_type value is much more flexible.

05

of 10

Variable Error Checking

We can also define this variable that can only be assigned values that we allow using the validating property, like this:

variable "instance_type" {
  type = string
  description = "Instance type of the EC2"

  validation {
    condition = contains(["t2.micro", "t3.small"], var.instance_type)
    error_message = "Value not allow."
  }
}

In the above file, we will use the contains() to check that the value of this instance_type variable is only in the allowed array. Otherwise, when we run the apply command, we will see an error in the error_message field.

Modify the terraform.tfvars file.

instance_type = "t3.micro"

Run apply.

terraform apply

╷
│ Error: Invalid value for variable
│
│   on variable.tf line 1:
│    1: variable "instance_type" {
│
│ Value not allow.
│
│ This was checked by the validation rule at variable.tf:5,3-13.
╵

Use validating to control the value of the variable you want. When you’re done with testing, modify the terraform.tfvars file as it was. Typically, when creating EC2, we will want to see its IP. To do that, we use the output block.

06

of 10

Output value

The value of the output block will be printed to the Terminal. The syntax is as follows:

To print the EC2 public_ip value, add the following code to the main.tf file

...

output "ec2" {
  value = {
    public_ip = aws_instance.hello.public_ip
  }
}

You rerun the apply command, and we will see the EC2 IP value printed to the Terminal.

terraform apply -auto-approve

...

Apply complete! Resources: 1 added, 0 changed, 0 destroyed.

Outputs:

ec2 = {
  "public_ip" = "52.36.124.230"
}

Now we know how to use variables and output. Next, what if we want to add another EC2? In the main.tf file, we will copy out one more EC2.

provider "aws" {
  region = "us-west-2"
}

data "aws_ami" "ubuntu" {
  most_recent = true

  filter {
    name   = "name"
    values = ["ubuntu/images/hvm-ssd/ubuntu-focal-20.04-amd64-server-*"]
  }

  owners = ["099720109477"]
}

resource "aws_instance" "hello1" {
  ami           = data.aws_ami.ubuntu.id
  instance_type = var.instance_type
}

resource "aws_instance" "hello2" {
  ami           = data.aws_ami.ubuntu.id
  instance_type = var.instance_type
}

output "ec2" {
  value = {
    public_ip1 = aws_instance.hello1.public_ip
    public_ip2 = aws_instance.hello2.public_ip
  }
}

We will add a resource block for the second EC2, and in the output, we will update it so that it can print the IPs of the two EC2 Instances. Everything is so far so good, but what if we want to create 100 EC2s now? We can copy out 100 resource blocks, but no one will do that. We will use the count property.

07

of 10

The count property

The count attribute is a Meta Argument in Terraform, not of the resource type of the Provider. In lesson 2, we said that the resource type only contains the properties provided by the Provider, and the Meta Argument is a property of Terraform. In other words, we can use it in any resource block. Update the main.tf file, which will generate 5 EC2.

provider "aws" {
  region = "us-west-2"
}

data "aws_ami" "ubuntu" {
  most_recent = true

  filter {
    name   = "name"
    values = ["ubuntu/images/hvm-ssd/ubuntu-focal-20.04-amd64-server-*"]
  }

  owners = ["099720109477"]
}

resource "aws_instance" "hello" {
  count         = 5
  ami           = data.aws_ami.ubuntu.id
  instance_type = var.instance_type
}

output "ec2" {
  value = {
    public_ip1 = aws_instance.hello[0].public_ip
    public_ip2 = aws_instance.hello[1].public_ip
    public_ip3 = aws_instance.hello[2].public_ip
    public_ip4 = aws_instance.hello[3].public_ip
    public_ip5 = aws_instance.hello[4].public_ip
  }
}

Now when I run apply, Terraform will generate 5 EC2s for me. You notice that in the output part, we will use the [] sign and the Index value of the resource to access the resource. Usually, to access the resource, we use the <RESOURCE TYPE>.<NAME> syntax, but when we use the count syntax, we will access the resource using the <RESOURCE TYPE>.<NAME>[index] syntax.

Now we have solved the problem of copying the resource out when we need to create it in large numbers, but we still have to write out each resource individually in the output part. We will solve it by using the for expression.

08

of 10

Expression For

The for expression allows us to iterate through a list, the syntax of the for statement:

for <value> in <list> : <return value>

We will use for to shorten the output of EC2. Update the main.tf file

...

resource "aws_instance" "hello" {
  count         = 5
  ami           = data.aws_ami.ubuntu.id
  instance_type = var.instance_type
}

output "ec2" {
  value = {
    public_ip = [ for v in aws_instance.hello : v.public_ip ]
  }
}

The above output will print the public_ip value, an IP array of all EC2 generated. If you want to print the result as { public_ip1: , public_ip2: }, you can use the format function.

09

of 10

Format function

The format function will help us concatenate strings and update the output as follows:

...

resource "aws_instance" "hello" {
  count         = 5
  ami           = data.aws_ami.ubuntu.id
  instance_type = var.instance_type
}

output "ec2" {
  value = { for i, v in aws_instance.hello : format("public_ip%d", i + 1) => v.public_ip }
}

Run the terraform plan to check, and we will see that the output will now be of the form { public_ip1: , public_ip2: }.

terraform plan

...
Changes to Outputs:
  + ec2 = {
      + public_ip1 = (known after apply)
      + public_ip2 = (known after apply)
      + public_ip3 = (known after apply)
      + public_ip4 = (known after apply)
      + public_ip5 = (known after apply)
    }

────────────────────────────────────────────────────────────────────────────────────────────────────────────────────────────

Note: You didn't use the -out option to save this plan, so Terraform can't guarantee to take exactly these actions if you
run "terraform apply" now.

Now the format of the output value is much easier to read.

10

of 10

Conclusion

So we’ve learned about some simple ways to program in Terraform. Use the variable attribute to hold the variable, the output format to display the output value, and the for expression to iterate over the array. In the following article, we will learn a few more functions through an example of using Terraform to deploy a Web page to S3.

Tags: Terraform

Tutorial 04 | Terraform

01 of 10 Introduction

02 of 10 Create EC2

03 of 10 Input variable declaration

04 of 10 Assign a value to a variable

05 of 10 Variable Error Checking

06 of 10 Output value

07 of 10 The count property

08 of 10 Expression For

09 of 10 Format function

10 of 10 Conclusion

Tutorial 03 | Terraform

Writing Terraform Scripts | Terraform

Comments 5,268